Изменение имени ПК на случайное при загрузке

Опубликовано admin - пт, 05/30/2014 - 14:53

Изменить можно с помощью VBS-скрипта в автозапуске (изменения применяются при следующей загрузке):

function RandomString()

    Randomize()

    dim CharacterSetArray
    CharacterSetArray = Array(_
        Array(4, "ABCDEFGHIJKLMNOPQRSTUVWXYZ"), _
        Array(4, "0123456789") _
    )

    dim i
    dim j
    dim Count
    dim Chars
    dim Index
    dim Temp

    for i = 0 to UBound(CharacterSetArray)

        Count = CharacterSetArray(i)(0)
        Chars = CharacterSetArray(i)(1)

        for j = 1 to Count

            Index = Int(Rnd() * Len(Chars)) + 1
            Temp = Temp & Mid(Chars, Index, 1)

        next

    next

    dim TempCopy

    do until Len(Temp) = 0

        Index = Int(Rnd() * Len(Temp)) + 1
        TempCopy = TempCopy & Mid(Temp, Index, 1)
        Temp = Mid(Temp, 1, Index - 1) & Mid(Temp, Index + 1)

    loop

    RandomString = TempCopy

end function

Name = "VPC" & RandomString()

Set objWMIService = GetObject("Winmgmts:root\cimv2")

' Call always gets only one Win32_ComputerSystem object.
For Each objComputer in _
    objWMIService.InstancesOf("Win32_ComputerSystem")

        Return = objComputer.rename(Name,Password,Username)
'         If Return <> 0 Then
'            WScript.Echo "Rename failed. Error = " & Err.Number
'         Else
'            WScript.Echo "Rename succeeded." & _
'                " Reboot for new name to go into effect"
'         End If

Next
Прикрепленные файлы
Вложение Размер
rename_pc.vbs 1.35 КБ
Теги
Яндекс.Метрика